Functions

def and return

def hyp(a, b) {
    return sqrt(a * a + b * b)
}
show hyp(3.0, 4.0)

Docstrings

A bare string as the first statement documents the function and compiles to nothing.

def double(x) {
    "twice the input"
    return 2.0 * x
}
show double(21.0)

Recursion

A double holds every integer up to 2^53 exactly, so a counter can stop the recursion with equality; a comparison such as n < 1.5 also stops it when n is not a whole number.

def fact(n) {
    if n < 1.5 {
        return 1.0
    }
    return n * fact(n - 1.0)
}
show fact(6.0)

Type annotations

Optional; the compiler checks them before the program runs.

def scale(v: Arr, s: Num) -> Arr {
    return v * s
}
show scale([1.0, 2.0], 10.0)

A def with no return gives nothing

A def that ends without a return is called as a statement. Its value is nothing: the compiler refuses show f(x) or f(x) + 1.0 for it.

def report(x) {
    show x + 1.0
}
report(5.0)

Early return

def clamp01(x) {
    if x < 0.0 { return 0.0 }
    if x > 1.0 { return 1.0 }
    return x
}
show clamp01(0.0 - 2.0)
show clamp01(0.4)
show clamp01(9.0)

Call before definition

Top-level defs are collected before anything runs, so source order does not matter.

show later(4.0)
def later(x) {
    return x * 10.0
}

Lambdas pass as arguments

A def can take a function value and call it.

def apply2(f, x) {
    return f(f(x))
}
show apply2(fn(t) -> t * t, 3.0)

Parameters shadow globals

x = 100.0
def f(x) {
    return x + 1.0
}
show f(5.0)
show x

Several results

return a, b gives two values, and the caller unpacks them on a line of its own; a, b = b, a swaps.

def divmod2(a, b) {
    q = floor(a / b)
    return q, a - q * b
}
q, r = divmod2(17.0, 5.0)
show q
show r
q, r = r, q
show q