Animation

An animation is a Viv program: it creates named objects, and transitions reveal, morph and move them. The program prints records; the page plays them back with a scrubber. Run a cell to see its output beside the expected one.

A stage, an object, a transition

stage opens an animation and gives it a coordinate window. Objects are created hidden; draw reveals a curve by drawing it on. Each call prints one record, which is what this page plays.

Viv [1]

x = linspace(0.0, 1.0, 5)
stage("A parabola, drawn on", 0.0, 1.0, 0.0, 1.0)
axes("x", "y")
curve("f", x, x * x)
draw("f", 1.5)

Morph, with a caption

morph moves a curve's points smoothly to new data over the given seconds. say sets the caption until the next say; a number given after the text is appended, which is how a caption reports a computed value.

Viv [2]

x = linspace(0.0, 1.0, 3)
stage("A line becomes a parabola", 0.0, 1.0, 0.0, 1.0)
curve("f", x, x)
draw("f", 1.0)
say("now square it; the midpoint falls to", 0.5 * 0.5)
morph("f", x, x * x, 2.0)

Running transitions together

Transitions run one after another. Between together() and apart() they start at the same moment, and the group lasts as long as its longest member. A label's text may carry TeX between dollars: write two backslashes for one.

Viv [3]

x = linspace(0.0, 1.0, 3)
stage("Together", 0.0, 1.0, 0.0, 1.0)
curve("f", x, x)
hline("half", 0.5)
label("name", "$y = \\tfrac12$", 0.8, 0.56)
together()
draw("f", 1.0)
fade_in("half", 0.5)
fade_in("name", 0.5)
apart()
wait(1.0)

A simulation drawn as it runs, with keyframes

frame(dt) advances the clock. An object set again later moves there over the time between: a ball drawn at two places with a frame between them glides from one to the other. In a keyframed animation objects are visible from creation; shapes (circle, rect, segment, poly) and dots with a radius are sized in the stage's units.

Viv [4]

stage("A bouncing ball", 0.0, 4.0, 0.0, 2.0)
hline("floor", 0.0)
fall = sqrt(2.0 / 4.9)
for k to 9.0 {
    t = 0.2 * k
    # time from the nearest top of a bounce: the ball falls from y = 2 and comes back up
    s = t - 2.0 * fall * floor(t / (2.0 * fall) + 0.5)
    circle("ball", 1.0 + t, 2.0 - 4.9 * s * s, 0.1)
    frame(0.2)
}

← Plotting Testing →